{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-23.05";
    nixpkgs-unstable.url = "github:nixos/nixpkgs/nixos-unstable";

    agenix.inputs.darwin.follows = "";
    agenix.inputs.home-manager.follows = "";
    agenix.url = "github:ryantm/agenix";
    flake-parts.url = "github:hercules-ci/flake-parts";
    nixinate.url = "github:matthewcroughan/nixinate";

    # attic.url = "github:zhaofengli/attic";
    pre-commit-hooks.url = "github:cachix/pre-commit-hooks.nix";
    sanctureplicum-nur.url = "git+https://gitea.pid1.sh/sanctureplicum/nur.git";
    valheim-server.url = "github:aidalgol/valheim-server-flake";
  };

  nixConfig = {
    substituters = [
      "https://cache.nixos.org"
      "https://cache.garnix.io"
      "https://pre-commit-hooks.cachix.org"
      "https://sanctureplicum.cachix.org"
    ];
    trusted-public-keys = [
      "cache.nixos.org-1:6NCHdD59X431o0gWypbMrAURkbJ16ZPMQFGspcDShjY="
      "cache.garnix.io:CTFPyKSLcx5RMJKfLo5EEPUObbA78b0YQ2DTCJXqr9g="
      "pre-commit-hooks.cachix.org-1:Pkk3Panw5AW24TOv6kz3PvLhlH8puAsJTBbOPmBo7Rc="
      "sanctureplicum.cachix.org-1:VztHStNqXs5pFZ0eNVoIfoqCaeKdNKRqkbNb8lYrqQ8="
    ];
  };

  outputs = {flake-parts, ...} @ inputs: let
    overlays = final: prev: rec {
      atuin = unstable.atuin;
      gitea-nyx = inputs.sanctureplicum-nur.packages.${prev.system}.gitea-nyx;
      unstable = import inputs.nixpkgs-unstable {
        inherit (prev) system;
      };
    };
  in
    flake-parts.lib.mkFlake {inherit inputs;} {
      flake = {
        nixosConfigurations.main-node = inputs.nixpkgs.lib.nixosSystem {
          system = "x86_64-linux";
          modules = [
            {
              _module.args.nixinate = {
                host = "main-node";
                buildOn = "local";
              };
              nixpkgs = {
                config.allowUnfree = true;
                overlays = [overlays];
              };
            }
            ./hosts/main-node
            ./config
            ./modules
            # inputs.attic.nixosModules.atticd
            inputs.agenix.nixosModules.default
            inputs.valheim-server.nixosModules.default
          ];
        };
      };

      perSystem = {
        pkgs,
        system,
        self',
        ...
      }: {
        apps = (inputs.nixinate.nixinate.${system} inputs.self).nixinate;

        checks.pre-commit-check = inputs.pre-commit-hooks.lib.${system}.run {
          src = ./.;
          hooks = {
            alejandra.enable = true;
            nil.enable = true;
          };
        };

        devShells.default = pkgs.mkShell {
          buildInputs = [inputs.agenix.packages.${system}.agenix];
          inherit (inputs.self.checks.${system}.pre-commit-check) shellHook;
        };

        formatter = pkgs.alejandra;
      };

      systems = ["x86_64-linux" "aarch64-linux" "aarch64-darwin" "x86_64-darwin"];
    };
}